REM #######################################################################<80
REM # *COMMENTED GUIDE* TEXT file for Ulf 'Don ULFonso' Muckel's             #
REM # <<Red Baron 2 / 3D - 'Flags 2 Fly' - Pack #06>>                        #
REM # 'LET YOUR *GEAR* THINK WHILE *YOU* FLY...!'                            #
REM #------------------------------------------------------------------------#
REM # 'Red Baron 2'  by 'Dynamix':                                           #
REM #                'Red Baron 2'                                           #
REM #                'Red Baron 3D'                                          #
REM #------------------------------------------------------------------------#
REM # SWF22          (F16 FLCS/F22 Pro + Stickworks' digital chipset)        #
REM # F22 Pro        (Thrustmaster's original chipset)                       #
REM # F 16 FLCS      (UNCONVERTED = *NO* 'FUZZY-LOGICS'!)                    #
REM # + TQS          (+ optional(?) RCS/ECS)                                 #
REM #------------------------------------------------------------------------#
REM # PROGRAM files  'Red_Baron_2.f22'                           (SWF22)     #
REM #                'Red_Baron_2_Auto-Time.f22'                 (SWF22)     #
REM #                'R_B_2.f22'                                 (F22 Pro)   #
REM #                'R_B_2_AT.f22'                              (F22 Pro)   #
REM #                'R_B_2_de.b50' (german)                     (F16 FLCS)  #
REM # 4 MACRO files  'Red_Baron_2.m22'                           (SWF22)     #
REM #                'R_B_2.m22'                                 (F22 Pro)   #
REM #                'R_B_2_de.m50' (german)                     (F16 FLCS)  #
REM #------------------------------------------------------------------------#
REM # written, tested and commented by Ulf 'Don ULFonso' Muckel: 01/10/15    #
REM # e-Mail:        Don.ULFonso@Thrustmaster-X-Files.de                     #
REM # Domain:        http://www.Thrustmaster-X-Files.de                      #
REM # Sub-Domains:   http://Set-Ups.Thrustmaster-X-Files.de                  #
REM #                http://Forum.Thrustmaster-X-Files.de                    #
REM #                http://Block50.Thrustmaster-X-Files.de                  #
REM ##########################################################################

REM #######################################################################<80
REM # PROGRAM file 'Red_Baron_2.f22' for MACRO file 'Red_Baron_2.m22'        #
REM # and SWF22 (F16 FLCS/F22 with Stickworks' digital upgrade chipset)      #
REM # with TQS and RCS /ECS (optional)                                       #
/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\
REM # PROGRAM file "R_B_2.f22" for MACRO file "R_B_2.m22"                    #
REM # and Thrustmaster F22 Pro (with original chipset)                       #
REM # with TQS and RCS /ECS (optional)                                       #
/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\
REM # for 'Red Baron 2 / 3D' by 'Dynamix',                                   #
REM # written, tested and commented by Ulf 'Don ULFonso' Muckel: 01/10/15    #
REM # Don.ULFonso@Thrustmaster-X-Files.de                                    #
REM # http://www.Thrustmaster-X-Files.de                                     #
REM ##########################################################################

    REM IMPORTANT NOTES: *BEFORE* DOWNLOAD to stick:
    REM ----------------------------------------------------------------------
    REM - YOU *MUST* TAKE A LOOK AT THE MACRO FILES ('.m22', '.tmm'):
    REM   - SEE '5. RADIO' SECTION ('Roger Wilco'):
    REM   - *SET-UP* [ALT F12] FOR 'ROGER WILCO' *TALK*!
    REM - BOTH *ANTENNA* AND *RANGE* KNOB *MUST* BE ~CENTERED!
    REM   - YOU *SHOULD* MOVE THE *ANT* ONCE WHEN YOU *START 1ST FLIGHT*
    REM - IF YOU DOWNLOAD *USING ANY EDITOR* (ANYONE *WITHOUT* 'Fox 2'?),
    REM   YOU *MUST NOT SAVE* THE (OPEN) FILE *AFTER DOWNLOAD*!
    REM - YOU *SHOULD* READ THIS 'TXT' 'UNCUT' *COMMENTED* FILE!
    REM - DO *NOT* MODIFY THESE SET-UPS' *LOGICAL* PROGRAMMING
    REM   IF YOU DO NOT *FULLY UNDERSTAND* THEIR *CAUSAL CONNECTIONS*!
    REM   (SEE 'TIP:IF YOU'D LIKE TO TRY TO *MODIFY*'-SECTION BELOW)
    REM   - ANY *MODIFICATIONS* WILL BE AT *YOUR OWN RISK*,
    REM   - I WILL *NOT* BE HELD *RESPONSIBILE* FOR ANY *CONSEQUENCES*!

    REM FOLLOW THESE DIRECTIONS - and your sticks SHOULD *NOT* melt...
    REM (This is *NO BUG* OR PROGRAM FILE ERROR -
    REM to understand WHY AND *HOW* this file works see REMs at flag defs!)

    //  ANNOTATION: *HOW TO READ* THIS FILE:
    //  ----------------------------------------------------------------------
    //  THIS FILE IS THE *SOURCE* FILE FOR ALL JOYSTICK PROGRAM FILES:
    //  it contains the *COMPLETE* PROGRAMMING INCLUDING ANY *ALTERNATIVES*
    //  to match the *SPECIFIC* STICKS' SYNTAX / RULES / LIMITATIONS;

    //  ALL STEPS OF 'LOGICAL PROGRAMMING' HAVE BEEN *COMMENTED*
    //  to GUIDE you through the *SET-UP PROCESS* and
    //  HELP TO *UNDERSTAND* how EACH SINGLE PIECE SUPPLEMENTS THE OTHERS;
    //  this is ESSENTIAL because *LOGICAL EQUATIONS* DEFINING *FLAGS*
    //  MUST BE SET-UP *ACCORDING* TO THE *SPECIFIC* TASK to be solved!
    //  Those NOTES STARTING WITH THE *SWF22* "COMMENT"-INDICATOR "//"
    //  are the 'WHYs' and 'HOWs' AT LENGTH,
    //  and in most cases REMOVED FROM THE SET-UP FILES;
    //  those NOTES STARTING WITH 'REM' ARE USED AS 'HEAD-LINE' *REMINDERS*
    //  and REMAIN IN THE SET-UP FILES.

    //  THE *JOYSTICK SPECIFIC ALTERNATIVES* ARE MARKED as follows:
    //  '+++' *F22 Pro* ONLY,
    //  '///' *SWF22* ONLY, and
    //  '>>>' *HOTAS Cougar* ONLY (removed since CONFIDENTIAL)!
    //  '!!!' *THOUGHTS* for e.g. COMING UPDATES (=MODIFICATIONS)... ;)
    //  '//' *AND* '// REM' *ALTERNATIVES* OFFERED but not used:
    //  IF you WOULD like to TRY ANY of them, simply *ENABLE* them
    //  BY *REMOVING* ALL '//' of the *CORRESPONDING PARAGRAPH*
    //  IN THE *CORRESPONDING SET-UP FILE* - *NOT* IN THIS COMMENTED *GUIDE*!
    //  (I'd recommend *OVERWRITING* THEM WITH 'SPACES' to keep layout)

>>> !!! Due to the CONFIDENTIAL DATA used in the *HOTAS Cougar* SET-UPs,
>>> !!! I *REMOVED* ANY SUCH *RED-HOT* (NOT *ALL*) *CONTENTS* USING '######'
>>> !!! (I suppose you won't like this, but will UNDERSTAND...)
>>> !!! so you will SEE *WHERE* TO EXPECT *NEW* OR *ENHANCED* FUNCTIONS ;)

    //  TIP: IF YOU'D LIKE TO TRY TO *MODIFY*:
    //  ----------------------------------------------------------------------
    //  IN *MOST* CASES you CANNOT AND *MUST NOT*
    //  use the techniques for THIS game's set-up as a TEMPLATE for others -
    //  but IF you UNDERSTAND GENERAL FLAGS' *FUNCTION*
    //  you might want to TRY *MODIFICATIONS* (maybe even with some success):
    //  if you do so, always KEEP IN MIND THAT *MOST* FLAGS here are
    //  *LINKED*, *COMBINED* AND *NESTED* TO *MULTIPLE SCOPES*,
    //  with *CROSS-OVER* REFERENCES ALL THROUGH THESE SET-UPS -
    //  if you CHANGE the 'WRONG' PART: 'Good luck an' enjoy yourself!'...
    //  YOU WON'T GET ANY 'COMPILING ERROR'-*MESSAGE*
    //  to EXPLAIN the 'STRANGE' *RESULTS*,
    //  ranging from 'just' ERRATIC *OUTPUT* (if you're LUCKY!)
    //  to a COMPLETELY 'LOCKED' *MACHINE*
    //  (*SWF22* USERS ONLY should simply *REBOOT* the PC,
    //  and the STICK WILL BE IN "WINDOWS"-MODE AGAIN:
    //  WITHOUT FLAG'S *OUTPUT* - and then: 'HAPPY BUG-HUNTING!'...
    //  *F22 Pro* USERS... eh... DO *NOT* HAVE THIS CHANCE:
    //  BE *SURE* TO SPARE ONE BUTTON FOR THE 'F22RST'-STATEMENT,
    //  and PRAY it MIGHT save you in the case-of-all-cases...)

    //  The PROGRAM & MACRO FILES for each TM's *F22* or *SWF22* 
    //  (and for the *HOTAS Cougar*, at least to some extent) are BASED
    //  on THIS 'COMMENTED GUIDE' FILE, but *CUT* 2 MATCH *SPECIFIC LIMITS*:
    //  both *SWF22* and *HOTAS Cougar* SUPPORT
    //  *GREATER FILE SIZE & LONG FILE NAMES*,
    //  *LONGER LINES AND MACRO DEFINITIONS* (< 255 CHARS. / see 'Block50'),
    //  *LONGER MACRO NAMES* (> 16 CHARACTERS),
    //  and *MORE FLAGS* (96 USED), respectively *LESS FLAGS* (32 USED),
    //  PLUS '/H' and '/N' CODES WITHIN '/I/O' or '/U/M/D' STATEMENTS,
    //  than the 'original' *F22*;
    //  the *SWF22* uses *DIFFERENT 'RAW' CODES* than the *F22*,
    //  the *HOTAS Cougar* NO 'RAW'-codes at all,
    //  but an ENHANCED AND SIMPLYFIED 'HARDWARE CHARACTER GENERATION'-SYSTEM;
    //  for *F22 COMPATIBILITY* I 'STUCK' TO *THESE 'OLD' TM LIMITS*
    //  *WHEREEVER POSSIBLE*, and *AVOIDED TO USE INCOMPATIBLE FUNCTIONS*
    //  (e.g. 'CMPLT' or 'CMPGT' for *F22 ONLY*,
    //  or 'USE MTX48' similar to 'BTN MT', or 'USE H#_4WAY' (both *SWF22*),
    //  thus I *ALWAYS* USE 'S3' AS '/I/O' SHIFT BUTTON
    //  and do NOT redefine using 'IOBTTN IS') -
    //  if for any reason I HAVE to use such *SPECIFIC* FUNCTIONS
    //  (e.g. for the *HOTAS Cougar* it would be shameful waste NOT to do so),
    //  you'll find the *ALTERNATIVES* EXPLAINED AS WELL!
    //  Nevertheless I limited myself to USE CORRECT '*SLASH* MODIFIERS'
    //  ACCORDING TO THE *SWF22*-RULES within THIS *COMMENTED* TEXT-FILE:
    //  some of the COMBINATIONS you'll find here will NOT work with the *F22*
    //  due to some *DIFFERENCES* (AS MENTIONED ABOVE),
    //  and the *HOTAS Cougar* is another chapter...
    //  ... OF COURSE you'll find the CORRECT *SPECIFIC* USAGE
    //  in the CORRESPONDING *SPECIFIC* SET-UPs! ;)

    //  (SINCE I ACTUALLY DO NOT *HAVE* ANY "F22" GEAR -
    //  and never had - I upgraded my old F16 FLCS to a 'grown up' *SWF22* -
    //  I CAN *ONLY* 'VERIFY' THE FILES FOR *F22* BY OPENING AND SAVING THEM
    //  IN THE (downloaded) 'F22 C&CC'
    //  (and THUS *ONLY* GUARANTEE CORRECT FILE/LINE SIZE
    //  AND STATEMENT 'GRAMMAR', BUT NOT RESULTING *OUTPUT*),
    //  AND *NOT* 'IN ACTION' (I CAN THUS *ONLY* GUARANTEE(!) FOR *SWF22*) -
    //  SO *PLEASE* MAIL IF YOU ENCOUNTER ANY PROBLEMS!
    //  (e.g. I do not really know yet whether my 'THR' STATEMENT -
    //  digital THROTTLE TYPE 2 with *ZERO STEPS* to work *FULLY ANALOG* -
    //  will work with TQS' ORIGINAL CHIP... HOPE so, at least it *SHOULD*...)

    //  FOR FURTHER INFORMATION / INSTRUCTIONS / GUIDES / TUTORIALS
    //  feel free to VISIT MY SITE (not only) ABOUT 'LOGICAL PROGRAMMING',
    //  the <<Thrustmaster 'BLOCK 50' - Compendium: The X-Files>>, at
    //  Domain:      http://www.Thrustmaster-X-Files.de
    //  Sub-Domains: http://Set-Ups.Thrustmaster-X-Files.de
    //               http://Forum.Thrustmaster-X-Files.de
    //               http://Block50.Thrustmaster-X-Files.de (to come)
    //  or (if your question should NOT be answered THERE) CONTACT ME
    //  e-Mail:      Don.ULFonso@Thrustmaster-X-Files.de

    //  If you like to PRINT this file, be sure to have some paper handy... ;)

REM ##########################################################################
REM # Flag settings:                                                         #
REM ##########################################################################
                                               REM LOGIC FLAGS will be DEFINED
                                               REM (and EXPLAINED generally)
                                               REM in the BUTTONS' SECTION(S)
                                               REM they are needed for...

    // NOTE:  The following TABLE is a COMPLETE listing of *ALL* FLAGS USED
    //        within *ANY* SET-UPs (sort of 'SUMMARY' OF *ALL* FILES):
    //        for *COMPATIBILITY* (=CONVERTING) REASONS
    //        FLAGS' USAGE starts with the MOST *IMPORTANT* FUNCTIONS
    //        (X1-X32: *HOTAS Cougar* 'KERNEL',
    //        to be 'completed' by X33-X48: *F22 Pro* "RANGE"),
    //        followed by ADDITIONAL 'GOODIES' (X49-X96: *SWF22* SUPPORT)
    //        to TWEAK your 'HOTAS'-equipment 'to the max'!

    //        EACH *SET-UP* for the *DIFFERENT* 'BLOCK 50'-STICKS
    //        will *ONLY* use (and be ABLE to handle)
    //        the *ACCORDING* TOTAL NUMBER of flags *SUPPORTED*!

    //        #########################################################------+
    // LOGIC  # 1      2      3      4      5      6      7      8    # 9    |
    // FLAGS  #ANT    ANT    ANT    ANT    ANT    ANT    ANT    ANT   #Var.4 |
    // TABLE  #(<------------up/cw---------ctr.----------dn/ccw-------#*F22* |
    // ########------+------+------+------+------+------+------+------#------+
    // #10    |11     12     13     14     15     16     17     18    #19    |
    // #VW/CAM|CAM    CAM    VW     VW     VW     VW     VW     CAM   #Var.4 |
    // #2Break|(<------------up/cw---------ctr.----------dn/ccw----->)#*F22* |
    // #######################################################################
    // #20    |21     22     23     24     25     26     27     28    |29    #
    // #S3    |PoV    PoV    PoV    PoV    PoV    PoV    PoV    PoV   |S3    #
    // #2Track|Fwd/Up FwdRgt Rgt    RgtBwd Bwd/Up BwdLft Lft    LftFwd|Loop  #
    // #######################################################################
    // #30    #31    #32     33    |34     35    |36     37    |38     39    #
    // #A.Plt.#Var.4 #A.Plt. A.Plt.|CAM    CAM   |PAD    PAD   |Pad-   Zoom- #
    // #MODE  #*F22* #Zoom-  Zoom+ |Zoom-  Zoom+ |Page-  Page+ |MODE   MODE  #
    // #Cougar#HOTAS##Cougar##################################################
    // #40    #41     42     43     44    #45     46    |47    #48    #49
    // #T2-5  #H2U    H2D    H2L    H2R   #TG1/O  TG1/I |TG1   #PULSE #  -
    // #      #(<--------TGTs----------->)#-TG2   -TG2  |-TG2  #2Comb.#   96
    // #########################################################F22Pro#SWF22->

REM ##########################################################################
REM # General settings:                                                      #
REM ##########################################################################

    MDEF r_b_2                                REM *F22 Pro*
    MDEF red_baron_2                          REM *SWF22*
>>> USE MDEF red baron 2                      REM *HOTAS Cougar*
    RATE 0                                    REM *F22 Pro* / *SWF22*
>>> USE RATE (20)                             REM *HOTAS Cougar*
                                              REM Typematic RATE [1/1000s]:
                                              REM try to set *NEAR* 0, or
                                              REM higher (if any problems).

        //  1st off, let's GENERATE a *GENERAL* 'PULSE'
        //  to *EMULATE* REPEATED SINGLE KEY-PRESSES
        //  in COMBINATION WITH BTNs / HATs *AS LONG AS HELD* -
        //  * NOTE: the 'PULSE'-FUNCTION works DIFFERENT than DOCUMENTED:
        //  - ACCORDING to 'APPLICATION NOTE 2a'
        //    the VALUES (*PULSE* 'ON' / 'OFF') *SHOULD* BE *MILLISECONDS*,
        //  - but they seem to be INFLUENCED BY OTHER FACTORS
        //    (maybe 'RATE'-SETTINGS, or CPU-SPEED, or MURPHY):
        //    though THIS 'PULSE' is SET-UP to pulse EACH 0.5 SECOND,
        //    in COMBIN. with its 'TOGGLE'-*STATE* in conjunction with BTNs
        //    to SLOW DOWN 50%, RESULTING in a *DEFINED* 'PULSE' of 1 SECOND,
        //    on MY PC and with a 'RATE' of '20' it's ACTUALLY ~0.25 SECONDS...
        //    (for 'Combat Flight Sim' I had to use a value of '30000' = 30s
        //    just to get something ~2.5s!)
        //  * NOTE: you CANNOT achieve SIMILAR RESULTS using 'STD. SYNTAX':
        //  - BTN H2L DLY(500) [any_macro]
        //    would be *INTERRUPTED* by ANY OTHER FUNCTION,
        //  - BTN H2L /H (DLY(500) [any_macro])
        //    would NOT WORK ('HELD' SEQUENCE) - but even IF it would,
        //  - the 'DLY'-STATEMENT would *SUPPRESS* ANY OTHER COMMAND,
        //  - 'HELD' COMBINATIONS (e.g. 'CTL a') PLUS 'DLY' would NOT WORK
        //    ('directly', that is, but you *COULD* USE 'indirect'
        //    'DELAYed' *RAW 'MAKE'- AND 'BREAK'-CODEs*)!

        REM -> *PULSE* AS LONG AS *HELD* 2 *COMBINE* WITH HATS
        REM (THX 2 Bob 'Sticky' Church 4 the basic idea 2 set-up 1 up-front):
        REM ------------------------------------------------------------------
        DEF X48      PULSE(60 440) (NOT S3 OR S3)

>>> USE #### ####### ### ##### #.###          REM (open '####' #### #####)
>>> USE #### ######  ### ##### #.###          REM (open '####' #### #####)

REM ##########################################################################
REM # Joystick settings:                                                     #
REM ##########################################################################

REM --------------------------------------------------------------------------
REM Trigger(s):                               (2-STAGE TRIGGER)
REM --------------------------------------------------------------------------

        REM *SEPARATE OUT* TG1 '/I' / '/O'
        REM (2 *TRACK* CHANGES OF S3-*STATE*):
        REM ------------------------------------------------------------------
        DEF X45      (TG1 AND NOT TG2) AND NOT S3 AND X47
        DEF X46      (TG1 AND NOT TG2) AND S3 AND X47

    BTN X45       /H WPN:'MG'                 REM ANLG. *NOT SUPPORTED*
    BTN X46          WPN:'MG'-UNJAM- 

    BTN TG2       /N WPN:'Rocket' 

        REM *LOOP* 2 *VERIFY* S3-*STATE*
        REM (2 *AUTOMATICALLY* *EXECUTE* CHANGES):
        REM ------------------------------------------------------------------
        DEF X47      TG1 AND NOT TG2

REM --------------------------------------------------------------------------
REM Buttons S1-4:                             (RED BUTTONS)
REM --------------------------------------------------------------------------

    BTN S1        /N WPN:'Rocket'

    BTN S2        /N WPN:'Bomb'

REM BTN S3                                    REM ([I/O shift button])

    BTN S4           VW/CAM:'PoV'BTN          REM 'RAW' *MAKE/BREAK* 4 '/P/R'

REM --------------------------------------------------------------------------
REM 'Coolie' H1:                              (LARGE GREY 'POV' HAT AT *TOP*)
REM --------------------------------------------------------------------------

REM BTN H1U          ANLG. 'PoV'              REM *SWF22* ONLY
REM BTN H1D          ANLG. 'PoV'              REM *SWF22* ONLY
REM BTN H1L          ANLG. 'PoV'              REM *SWF22* ONLY
REM BTN H1R          ANLG. 'PoV'              REM *SWF22* ONLY

    //  *USUALLY* I DO *NOT* USE H1 AS A 'POV COOLIE' (FULLY *ANALOG*);
    //  - in THIS GAME, *SWF22*-USERS *SHOULD NOT* USE H1 AS 'PoV COOLIE' -
    //    NOT *ANALOG WITHOUT DIGITAL MODIFICATION*, that is -
    //    for IF you do, you'll ALWAYS *END* IN'*MG*-VW' -
    //    NO MATTER *WHAT* HAS BEEN YOUR *LAST ACTIVE* 'VW/CAM' :( ...
    //    since THIS *WOULD* MESS-UP WITH MY 'TWISTING *VW/CAM*-SELECTION',
    //    I have *MODIFIED* THE CORRESPONDING SECTION 8)
    //    2 *AUTOMATIC.* TAKE YOU BACK ('RE-DIRECT') 2 THE 'CORRECT' VW/CAM!
    //  - *F22 Pro*-USERS DO *NOT* HAVE ANY 'PoV'-SUPPORT :( at all,
    //    so THEY might just LEAVE this SECTION *EMPTY* (*NO* OUTPUT at all),
    //    or (AB)USE *H1* 4 WHATEVER they like...

REM --------------------------------------------------------------------------
REM 'Coolie' H2:                              (SMALL BLACK HAT *LEFT*)
REM --------------------------------------------------------------------------

    //  H2 in my files is *ALWAYS* USED FOR 'TARGETING',
    //  since this IMHO is the HAT MOST *EASY TO HANDLE*:

REM BTN H2U          TGT:'BORESIGHT'          REM LGCL. EQUATION 2 'PULSE'
REM BTN H2D    /O    TGT:'Foe'                REM LGCL. EQUATION 2 'PULSE'
REM            /I    TGT:'Landmark'           REM LGCL. EQUATION 2 'PULSE'
REM BTN H2L    /O    TGT:'Foe'Nearest         REM LGCL. EQUATION 2 'PULSE'
REM            /I    TGT:'Friendly'           REM LGCL. EQUATION 2 'PULSE'
REM BTN H2R    /O    TGT:'Foe'Attacker        REM LGCL. EQUATION 2 'PULSE'
REM            /I    TGT:'Flight'             REM LGCL. EQUATION 2 'PULSE'

        REM *AUTOMATIC* '(*PULSE*=)CYCLE TGTs'-FUNCTION
        REM (2 *REPLACE* *MANUAL* 'Press' and 'Press' and 'Press again'...
        REM BUT *ONLY* 4 *ANY 'PADLOCK'* CURRENTLY *ACTIVE* -
        REM *ELSE* EACH '/P /R' WILL 'CYCLE' *1 STEP*
        REM AND *HOLD* 'PADLOCK* 4 *EXACTLY AS LONG* AS HELD,
        REM THEN *RETURN* 2 *LAST* 'VW/CAM' *ACTIVE*):
        REM ------------------------------------------------------------------
        DEF X41      H2U AND X48
        DEF X42      (H2D AND (NOT (X2 OR X3))) OR (H2D AND (X2 OR X3) AND X48*)
        DEF X43      (H2L AND (NOT (X2 OR X3))) OR (H2L AND (X2 OR X3) AND X48*)
        DEF X44      (H2R AND (NOT (X2 OR X3))) OR (H2R AND (X2 OR X3) AND X48*)

    BTN X41       /N TGT:'BORESIGHT'
    BTN X42    /O /N TGT:'Foe'
               /I /N TGT:'Landmark'
    BTN X43    /O /N TGT:'Foe'Nearest
               /I /N TGT:'Friendly'
    BTN X44    /O /N TGT:'Foe'Attacker
               /I /N TGT:'Flight'

REM --------------------------------------------------------------------------
REM 'Coolie' H3:                              (SMALL BLACK HAT *RIGHT*)
REM --------------------------------------------------------------------------

REM BTN H3U          CAM:'Zoom'+              REM LGCL. EQUATION
REM BTN H3D          CAM:'Zoom'-              REM LGCL. EQUATION
REM BTN H3L          KNEE:'Page'-             REM LGCL. EQUATION 2 'PULSE'
REM BTN H3R          KNEE:'Page'+             REM LGCL. EQUATION 2 'PULSE'

        REM 'ZOOM' *NOT ONLY* IF *ANY 'CAM'* CURRENTLY *ACTIVE*:
        REM ------------------------------------------------------------------
        DEF X34      ((H3U AND NOT S3) OR (H3D AND S3))
        DEF X35      ((H3D AND NOT S3) OR (H3U AND S3))

    BTN X34       /H CAM:'Zoom'+
    BTN X35       /H CAM:'Zoom'-

        REM ...FOR *IF* 'CAM' CURRENTLY *NOT* ACTIVE - *ACTIVATE* IT
        REM (*TEMPORARY* 'OVERRIDE', see 'ANT'-SECTION):
        REM ------------------------------------------------------------------
        DEF X39      ((H3U OR H3D) AND (NOT (X1 OR X2 OR X8)) AND NOT X39*) OR (DELAY(500) ((NOT (H3U OR H3D)) AND (NOT (X1 OR X2 OR X8)) AND X39*))

+++     REM *F22 Pro* ONLY:
+++     REM *VARIABLE* 4 *LONG EQUATIONs* 2 MATCH *LINE-LIMIT <80 CHARs.*:
+++     REM ------------------------------------------------------------------
+++     DEF X39 ((H3U OR H3D) AND (NOT (X1 OR X2 OR X8)) AND NOT X39*) OR X19
+++     DEF X19 DELAY(500) ((NOT (H3U OR H3D)) AND (NOT (X1 OR X2 OR X8)) AND X39*)

    BTN X39       /T CAM:'Chase'Close
                  /T ^

 // WE *SPARE* ONE FLAG USING THE LINES ABOVE
 // for we *NEED* TO (due to *COMPATIBILITY*:
 // while *SWF22*-LIMIT OF *96* IN MOST CASES WILL BE *MORE THAN ENOUGH* :D ,
 // *48* FOR THE *F22 Pro* OFTEN SEEM 2 'RUN OUT' 2 FAST ;) ,
 // NOT 2 SPEAK OF THESE 'POOR' *32* FOR THE *HOTAS Cougar* :( ...)
 // in fact, THIS '*DOUBLE* TOGGLE' OF ABOVE IS NECESSARY 
 // 2 'EMULATE' A *SINGLE* KEY-PRESS / MACRO AT EACH 'TOGGLE-*STATE'
 // BY 'SYNCHRONIZING' TO ITS *TYPICAL* 'RHYTHM' (ON-OFF, ON-OFF,...):
 //
 //     DEF X39      ((H3U OR H3D) AND (NOT (X1 OR X2 OR X8)) AND NOT X39*) OR (DELAY(500) ((NOT (H3U OR H3D)) AND (NOT (X1 OR X2 OR X8)) AND X39*))
 //     DEF X49      X39*
 //
 // BTN X49       /N CAM:'Chase'Close

        REM '*PULSE* (=TURN) PAGEs' *NOT ONLY* IF 'KNEEPAD'-VW CURR. *ACTIVE*:
        REM ------------------------------------------------------------------
        DEF X36      ((H3L AND NOT S3) OR (H3R AND S3)) AND ((X7 AND X48* AND NOT X30*) OR NOT X7)
        DEF X37      ((H3R AND NOT S3) OR (H3L AND S3)) AND ((X7 AND X48* AND NOT X30*) OR NOT X7)

+++     REM *F22 Pro* ONLY:
+++     REM *VARIABLE* 4 *LONG EQUATIONs* 2 MATCH *LINE-LIMIT <80 CHARs.*:
+++     REM ------------------------------------------------------------------
+++     DEF X31      (H3L AND NOT S3) OR (H3R AND S3)
+++
+++     DEF X36      X31 AND ((X7 AND X48* AND NOT X30*) OR NOT X7)
+++     DEF X37      X31 AND ((X7 AND X48* AND NOT X30*) OR NOT X7)

    BTN X36          KNEE:'Page'-
    BTN X37          KNEE:'Page'+

        REM ...FOR *IF* 'KNEEPAD'-VW CURRENTLY *NOT* ACTIVE - *ACTIVATE* IT
        REM (*TEMPORARY* 'OVERRIDE', see 'ANT'-SECTION):
        REM ------------------------------------------------------------------
        DEF X38      ((H3L OR H3R) AND NOT X7 AND NOT X38*) OR (DELAY(500) ((NOT (H3L OR H3R)) AND NOT X7 AND X38*))

+++     REM *F22 Pro* ONLY:
+++     REM *VARIABLE* 4 X38's *EQUATION* 2 MATCH *LINE-LIMIT <80 CHARs.*:
+++     REM ------------------------------------------------------------------
+++     DEF X38      ((H3L OR H3R) AND NOT X7 AND NOT X38*) OR (X9 AND X38*)
+++     DEF X9       DELAY(500) ((NOT (H3L OR H3R)) AND NOT X7 AND X38*)

    BTN X38       /T VW:'Kneepad'
                  /T ^

REM --------------------------------------------------------------------------
REM 'Coolie' H4:                              (HAT ON *LEFT SIDE* OF STICK)
REM --------------------------------------------------------------------------
               
    BTN H4U       /N WING:"Engage!"           REM DGTL. PROGR. (STD. SYNTAX)
    BTN H4D       /N WING:"Formation!"        REM DGTL. PROGR. (STD. SYNTAX)
REM BTN H4L          NAV:'Time'-              REM LGCL. EQUATION 4 'SECURITY'
REM BTN H4R          NAV:'Time'+              REM LGCL. EQUATION 4 'SECURITY'

        REM *EN-/DISABLE* 'TIME-COMPRESSION' *ONLY* IF 'AUTOPILOT' *ENABLED*
        REM (just 4 'SECURITY' REASONS...):
        REM ------------------------------------------------------------------
        DEF X32      ((H4L AND NOT S3) OR (H4R AND S3)) AND X48* AND X30*
        DEF X33      ((H4R AND NOT S3) OR (H4L AND S3)) AND X48* AND X30*

        REM SET-UP 'AUTOPILOT'-*MODE*:
        REM ------------------------------------------------------------------
        DEF X30      ((T7 OR T8) AND NOT X30*) OR (NOT (T7 OR T8) AND X30*)

 //     REM *ALTERNATIVE*:
 //     REM *NO RESTRICTION* TO 'ENABLED AUTOPILT'...
 //     REM (SEE 'Red_Baron_2_Auto-Time.f22' / 'R_B_2_AT.f22'):
 //     REM ------------------------------------------------------------------
 //     REM *EN-/DISABLE* 'TIME-COMPRESSION':
 //     REM ------------------------------------------------------------------
 //     DEF X32      ((H4L AND NOT S3) OR (H4R AND S3)) AND X48*
 //     DEF X33      ((H4R AND NOT S3) OR (H4L AND S3)) AND X48*
 //
 //     REM ...and *ENABLE* 'AUTOPILOT' IF 'OFF' *BUT* 'TIME-COMPRESSION'
 //     REM (just 4 'SECURITY' REASONS...):
 //     REM ------------------------------------------------------------------
 //     DEF X30      (H4L OR H4R) AND (NOT (T7 OR T8))
 //
 // BTN X30      NAV:'AUTOPlt'Full

    BTN X32       /N NAV:'Time'-
    BTN X33       /N NAV:'Time'+

REM ##########################################################################
REM # TQS settings:                                                          #
REM ##########################################################################

REM --------------------------------------------------------------------------
REM ANTENNA RING                              (center detent)
REM --------------------------------------------------------------------------
    REM *F22* ANT SENSE/DIRECTION:          | *SWF22* / *HOTAS Cougar*:
    REM ------------------------------------+---------------------------------
    REM       UP <- CTR.DETENT -> DOWN      |       DOWN <- CTR.DETENT -> UP
    REM 1 [#] [cw] [ccw] [ctr]              | 1 [#] [ccw] [cw] [ctr]
    REM 2 [#] [fullcw]..[ctr]..[fullccw]    | 2 [#] [fullccw]..[ctr]..[fullcw]

    REM IMPORTANT NOTE: *BEFORE* you start a flight:
    REM ----------------------------------------------------------------------
    REM - THE *ANT* RING *SHOULD* BE CENTERED,
    REM - BUT KEEP IN MIND FLAGS WILL OUTPUT ASSIGNED KEYS AUTOMATICALLY
    REM   ('HELP' OR 'SEARCH' MIGHT POP-UP *ONCE* AFTER DOWNLOAD)!

    ANT 2 9          X1 X8 X7 X6 X5 X4 X3 X2 X1 REM *SWF22*
REM ANT 2 9          X1 X2 X3 X4 X5 X6 X7 X8 X1 REM *F22 Pro*

        REM 'LIST' ALL BTNs which would *BREAK* the VIEW CURRENTLY *ACTIVE*
        REM (2 BE *REFERRED 2* BY 'VWs/CAMs'):
        REM ------------------------------------------------------------------
        DEF X10      NOT H2M OR NOT H1M OR (X38* OR X39*) OR (T3 OR T2 OR T5 OR T4)

        REM *LINK* 'VWs/CAMs' 2 'LIST'
        REM (2 ENABLE *RE-DIRECTION* 2 CURRENT *ACTIVE* VW):
        REM ------------------------------------------------------------------
        DEF X11      X1 AND NOT X10           REM LGCL. EQUATIONs USED
        DEF X12      X2 AND NOT X10           REM 2 ENABLE 'RE-DIRECTION'
        DEF X13      X3 AND NOT X10           REM 2 *LAST* 'VW/CAM' *ACTIVE*
        DEF X14      X4 AND NOT X10           REM 4 FUNCTIONs *BREAKING*
        DEF X15      X5 AND NOT X10           REM (= SWITCHING) 'VWs/CAMs'
        DEF X16      X6 AND NOT X10           REM (such as e.g. 'PADLOCK'),
        DEF X17      X7 AND NOT X10           REM OR CROSS-LINKED EQUATIONs
        DEF X18      X8 AND NOT X10           REM USED 2 *TEMPORARY 'OVERRIDE.

    REM -> 'TWISTING' VIEW *TYPE* SELECTION:
    REM ----------------------------------------------------------------------
    BTN X11       /N CAM:'Tgt/REVERSE'        REM cw.  = full UP
    BTN X12       /N CAM:'U_2_Tgt'            REM            |
    BTN X13       /N VW:'U_2_Tgt'             REM            |
    BTN X14          VW:'MG'                  REM            |
    BTN X15       /N VW:'Cockpit'             REM ctr. = ctr. DETENT
    BTN X16          VW:'Instruments'         REM            |
    BTN X17       /N VW:'Kneepad'             REM            |
    BTN X18       /N CAM:'Chase'Close         REM            |
    REM X11       /N CAM:'Tgt/REVERSE'        REM ccw. = full DOWN

REM --------------------------------------------------------------------------
REM RANGE KNOB                                (NO center detent)
REM --------------------------------------------------------------------------
    REM *F22* RNG SENSE/DIRECTION:          | *SWF22* / *HOTAS Cougar*:
    REM ------------------------------------+---------------------------------
    REM       LFT <\________/> RGT          |       RGT <\________/> LFT
    REM 1 [#] [cw] [ccw]                    | 1 [#] [ccw] [cw]
    REM 2 [#] [fullcw]...[fullccw]          | 2 [#] [fullccw]...[fullcw]

    REM IMPORTANT NOTE: *BEFORE* you start a flight:
    REM ----------------------------------------------------------------------
    REM - THE *RANGE* KNOB *SHOULD* BE ~CENTERED! (IF you USE it, that is...)

REM RNG

    BTN T6        /N ENG:I/O

REM --------------------------------------------------------------------------
REM 'Coolie' on TQS:                           (RADIO SWITCH)
REM --------------------------------------------------------------------------

        REM GENERATE A *QUICK PULSE* WHENEVER S3 *CHANGES*
        REM (THX 2 Bob 'Sticky' Church 4 his 'Red Baron Views):
        REM ------------------------------------------------------------------
        DEF X20       (S3 AND NOT X29) OR (X29 AND NOT S3)
        DEF X29       S3

        REM 'PoV' BASED on Bob 'Sticky' Church's 'Red Baron Views'
        REM (I just *REPLACED* 'HAT 3' BY TQS' 'COOLIE' T2-5):
        REM ------------------------------------------------------------------
        DEF X21      (T3 AND (NOT (T5 OR T4))) AND NOT X20
        DEF X22      (T3 AND T4) AND NOT X20
        DEF X23      (T4 AND (NOT (T3 OR T2))) AND NOT X20
        DEF X24      (T4 AND T2) AND NOT X20
        DEF X25      (T2 AND (NOT (T5 OR T4))) AND NOT X20
        DEF X26      (T2 AND T5) AND NOT X20
        DEF X27      (T5 AND (NOT (T3 OR T2))) AND NOT X20
        DEF X28      (T5 AND T3) AND NOT X20

   BTN X21     /O /N CTL KP8                  REM Look up 45
               /I /N KP5                      REM Look straight up
   BTN X22     /O /N KP9                      REM Look forward/right
               /I /N CTL KP9                  REM Look forward/right/up
   BTN X23     /O /N KP6                      REM Look right
               /I /N CTL KP6                  REM Look right/up
   BTN X24     /O /N KP3                      REM Look back/right
               /I /N CTL KP3                  REM Look back/right/up
   BTN X25     /O /N KP2                      REM Look back
               /I /N CTL KP2                  REM Look back/up
   BTN X26     /O /N KP1                      REM Look back/left
               /I /N CTL KP1                  REM Look back/left/up
   BTN X27     /O /N KP4                      REM Look left
               /I /N CTL KP4                  REM Look left/up
   BTN X28     /O /N KP7                      REM Look forward/left
               /I /N CTL KP7                  REM Look forward/left/up

REM --------------------------------------------------------------------------
REM DOGFIGHT SWITCH:                          (ROCKER)
REM --------------------------------------------------------------------------
                                              REM T7 <- ctr. -> T8
                                              REM (/U)  (/M)   (/D)

    BTN T7     /P    NAV:'AUTOPlt'Level
               /R    NAV:'AUTOPlt'OFF
    BTN T8     /P    NAV:'AUTOPlt'Full
               /R    NAV:'AUTOPlt'OFF

REM --------------------------------------------------------------------------
REM SPEED BRAKE:
REM --------------------------------------------------------------------------
                                              REM T9(lft) <- ctr. -> (rgt) T10
                                              REM (temp.)            (Un/Lock)

    BTN T9           VW/CAM:'Bore'OVERRIDE    REM 'RAW' *MAKE/BREAK* 4 '/P/R'

    //  2 *ALTERNATIVES* 4 '*SINGLE*-/*MULTI*-PLAYER':
    //  - '*SINGLE*-PLAYER' AS *DEFAULT*,
    //  - '*MULTI*-PLAYER' 2 BE *ENABLED* BY *CHANGING 'REMs'*
    //    ('Roger Wilco' is FREE, and by the way -
    //    since you ALREADY *HAVE* spent quite some money for your TM gear,
    //    you should NOT be complaining about the price for a headset...) ;)

    REM IMPORTANT NOTES 4 '*MULTI*-PLAYER': *BEFORE* DOWNLOAD to stick:
    REM ----------------------------------------------------------------------
    REM - YOU *MUST* TAKE A LOOK AT THE '.m22' MACRO FILE:
    REM   - SEE '5. RADIO' SECTION ('Roger Wilco'):
    REM   - *SET-UP* [ALT F12] FOR 'ROGER WILCO' *TALK*!

REM 4 '*SINGLE*-PLAYER':
REM --------------------------------------------------------------------------
    BTN T10    /P /N OPT:'Pause'
               /R    OPT:'Pause'

REM 4 '*MULTI*-PLAYER':
REM --------------------------------------------------------------------------
REM BTN T10          RADIO:'Roger_Wilco'P/R   REM 'RAW' *MAKE/BREAK* 4 '/P/R'

REM --------------------------------------------------------------------------
REM TRACKBALL:
REM --------------------------------------------------------------------------

    REM *DISABLE* 'MOUSE' (TRACKBALL, TRACKSTICK) FOR *F22* / *SWF22*:
   
    USE      NOMOUSE                          REM NOT *NEEDED* for *SWF22*

REM USE      MTYPE A2                         REM MTYPE  Left Btn  Right Btn
                                              REM A1     T1        T6
                                              REM A2     T6        T1
                                              REM A3     T1        /
                                              REM A4     T6        /
                                              REM A5*    /         / 
                                              REM   *    (only mouse movement)

REM USE      MSENS 50                         REM Trackball SPEED (*SWF22*)
                                              REM (mouse NOT afflicted)
                                              REM (DEFAULT speed: ~ MSENS 25)

                                              REM           T14(up)
                                              REM              |
                                              REM (lft)T12 -- ctr. -- T11(rgt)
                                              REM (bwd)        |         (fwd)
                                              REM           T13(dn)

        REM TQS' *TRACKSTICK*'s WAY 2 SAY 'NOT H#*M*':
        REM ------------------------------------------------------------------
        DEF X40      (T11 OR T12 OR T13 OR T14)

    BTN X40          VW/CAM:'PoV'BTN+AUTOLevel REM 'RAW' *MAKE/BREAK* 4 '/P/R'

 // ...THIS is just some MORE 'SOPHISTICATED' way...
 // COMPARED 2 '*STANDARD* SYNTAX', as you're USED (SEE BELOW):
 // --------------------------------------------------------------------------
 //
 // BTN T11          VW/CAM:'PoV'BTN+AUTOLevel
 // BTN T12          VW/CAM:'PoV'BTN+AUTOLevel
 // BTN T13          VW/CAM:'PoV'BTN+AUTOLevel
 // BTN T14          VW/CAM:'PoV'BTN+AUTOLevel

    BTN T1           !EJECT!

REM CHECK 6!###############################################################EoF